cmake_minimum_required(VERSION 3.10.0)
project(snipplib VERSION 0.1.0 LANGUAGES CXX)

option(SNPLIB_BUILD_EXAMPLES "Build examples" ON)

option(SNPLIB_USE_SPDLOG "Use of spdlog library" ON)

if(SNPLIB_USE_SPDLOG)
    include(FetchContent)
    # find_package(spdlog CONFIG)
    if(NOT spdlog_FOUND)
        FetchContent_Declare(
            spdlog
            GIT_REPOSITORY "https://github.com/gabime/spdlog.git"
            GIT_TAG "v1.17.0"
            GIT_SHALLOW TRUE
            GIT_SUBMODULES ""
            GIT_PROGRESS TRUE
            # CMAKE_ARGS
            # -DSPDLOG_USE_STD_FORMAT=ON
            # -DSPDLOG_FMT_EXTERNAL=OFF
            OVERRIDE_FIND_PACKAGE
        )

        set(SPDLOG_USE_STD_FORMAT ON CACHE INTERNAL "Use of C++20 std::format")
        set(SPDLOG_FMT_EXTERNAL
            OFF
            CACHE INTERNAL
            "Turn off external fmt library"
        )
        set(SPDLOG_INSTALL ON CACHE BOOL "Enable spdlog installation" FORCE)
        FetchContent_MakeAvailable(spdlog)
    endif()
endif(SNPLIB_USE_SPDLOG)

set(LIB_HEADERS
    include/snipplib/concepts/snplib_concepts.h
    include/snipplib/concepts/snplib_traits.h
    include/snipplib/utils/snplib_hash.h
    include/snipplib/utils/snplib_string.h
    include/snipplib/utils/snplib_keyvalue_expr.h
    include/snipplib/utils/snplib_logger.h
    include/snipplib/utils/snplib_utils.h
    include/snipplib/containers/snplib_hmap.h
    include/snipplib/containers/snplib_hvec.h
    include/snipplib/serialization/snplib_serialization.h
    include/snipplib/network/snplib_endpoint.h
)

add_library(${PROJECT_NAME} INTERFACE ${LIB_HEADERS})
target_compile_features(${PROJECT_NAME} INTERFACE cxx_std_23)
target_include_directories(
    ${PROJECT_NAME}
    INTERFACE
        "$<BUILD_INTERFACE:${CMAKE_CURRENT_LIST_DIR}/include>"
        "$<INSTALL_INTERFACE:include/${PROJECT_NAME}>"
)
if(SNPLIB_USE_SPDLOG)
    target_compile_definitions(
        ${PROJECT_NAME}
        INTERFACE
            SPDLOG_USE_STD_FORMAT=1
            SPDLOG_FMT_EXTERNAL=0
            SNPLIB_SPDLOGGER=1
    )
    target_link_libraries(${PROJECT_NAME} INTERFACE spdlog::spdlog_header_only)
endif()

if(SNPLIB_BUILD_EXAMPLES)
    set(EXAM_STRING str_exam)
    add_executable(${EXAM_STRING} examples/str_exam.cpp)
    target_link_libraries(${EXAM_STRING} ${PROJECT_NAME})

    set(EXAM_HMAP hmap_example)
    add_executable(${EXAM_HMAP} examples/hmap_example.cpp)
    target_link_libraries(${EXAM_HMAP} ${PROJECT_NAME})

    set(EXAM_HVEC hvec_example)
    add_executable(${EXAM_HVEC} examples/hvec_example.cpp)
    target_link_libraries(${EXAM_HVEC} ${PROJECT_NAME})

    set(EXAM_LOGGER logger_example)
    add_executable(${EXAM_LOGGER} examples/logger_exam.cpp)
    target_link_libraries(${EXAM_LOGGER} ${PROJECT_NAME})
endif()

include(GNUInstallDirs)
include(CMakePackageConfigHelpers)

install(
    TARGETS ${PROJECT_NAME}
    EXPORT ${PROJECT_NAME}_Targets
    LIBRARY DESTINATION ${CMAKE_INSTALL_LIBDIR}
    RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR}
)

set(SNPLIB_CONFIG_INSTALLDIR
    ${CMAKE_INSTALL_LIBDIR}/cmake/${PROJECT_NAME}
    # CACHE PATH
    # "install path for generated library config files"
)
set(SNPLIB_HEADERS_INSTALLDIR
    ${CMAKE_INSTALL_INCLUDEDIR}/${PROJECT_NAME}
    # CACHE PATH
    # "install path for headers"
)

configure_package_config_file(
    "${PROJECT_SOURCE_DIR}/${PROJECT_NAME}Config.cmake.in"
    "${PROJECT_BINARY_DIR}/${PROJECT_NAME}Config.cmake"
    INSTALL_DESTINATION ${SNPLIB_CONFIG_INSTALLDIR}
    PATH_VARS SNPLIB_HEADERS_INSTALLDIR
)

install(
    EXPORT ${PROJECT_NAME}_Targets
    FILE ${PROJECT_NAME}Targets.cmake
    NAMESPACE ${PROJECT_NAME_NAMESPACE}::
    DESTINATION ${SNPLIB_CONFIG_INSTALLDIR}
)
install(
    FILES
        "${PROJECT_BINARY_DIR}/${PROJECT_NAME}Config.cmake"
        "${PROJECT_BINARY_DIR}/${PROJECT_NAME}ConfigVersion.cmake"
    DESTINATION ${SNPLIB_CONFIG_INSTALLDIR}
)
install(FILES ${SNPLIB_SRC} DESTINATION include/${PROJECT_NAME})

# uninstall target
if(NOT TARGET uninstall)
    configure_file(
        "${CMAKE_CURRENT_SOURCE_DIR}/cmake_uninstall.cmake.in"
        "${CMAKE_CURRENT_BINARY_DIR}/cmake_uninstall.cmake"
        IMMEDIATE
        @ONLY
    )

    add_custom_target(
        uninstall
        COMMAND
            ${CMAKE_COMMAND} -P
            ${CMAKE_CURRENT_BINARY_DIR}/cmake_uninstall.cmake
    )
endif()